半小时完成一个湿度温度计

//这个是Arduino的标准库，其中提供了I2C接口的操作，这里不需要程序员自己操作I2C接口，是由下面的液晶板代码间接操作的
#include <Wire.h> 
//这个是液晶屏的代码库，是由器件厂商提供的，目前绝大多数的器件都会有厂商提供的软件包（或者叫驱动）来完成器件的操作
#include <LiquidCrystal_I2C.h>
//这个是温度、湿度传感器的软件包
#include <dht11.h>

//A0是温度、湿度传感器的接口号
#define DHT11PIN A0
//声明一个变量来操作传感器
dht11 DHT11;

//同样是声明一个变量来操作液晶屏，0x27是LCD地址，这个是器件手册中给出的，照抄就好
//16*2字符，这也是器件手册中的
LiquidCrystal_I2C lcd(0x27,16,2);  // set the LCD address to 0x27 for a 16 chars and 2 line display

//所有的Arduino程序都分为setup、loop两部分，前者作为正式工作前环境准备、初始化等工作，后者是一个工作循环
void setup()
{
  lcd.init();                      //初始化LCD
 
  //打开背光
  lcd.backlight();
  //下面三行是显示一个简单的启动信息，相当于一般软件的启动页
  lcd.print("Temperature &");
  lcd.setCursor(1,1);  //设置光标位置
  lcd.print("    Humidity");

  //下面三行是初始化串口，从而把温度、湿度的值实时传递到桌面电脑
  //在这个试验中实际串口是没有用的。我曾经把这个数据连接到微信公众号，从而对微信公众号说一句“温度”，就得到房间的温度值
  Serial.begin(9600);
  Serial.println("DHT11 Monitoring");
  Serial.print("\n");
}

//工作主循环
void loop()
{
  char strTemp[0x20],strHumid[0x20];
	//读温度、湿度值
  int val = DHT11.read(DHT11PIN);
  Serial.print("Read sensor: ");
  switch (val)
  {  
//这个switch是用于判断读取值的异常情况，是器件手册中给出的，看下面的信息应当不难理解
//通常一个新手跟专业人员比较大的区别之一就在异常的处理，专业人员不会报有任何幻想，会尽力的处理掉所有异常情况
  case DHTLIB_OK:
    Serial.println("OK");
    break;
  case DHTLIB_ERROR_CHECKSUM: 
    Serial.println("Checksum error"); 
    break;
  case DHTLIB_ERROR_TIMEOUT: 
    Serial.println("Time out error"); 
    break;
  default: 
    Serial.println("Unknown error"); 
    break;
  }

//在串口输出温度湿度值
  snprintf(strHumid,0x20,"%02d%%",(int)DHT11.humidity);
  snprintf(strTemp,0x20,"%02dC",(int)DHT11.temperature);
  Serial.println(strHumid);
  Serial.println(strTemp);

//在lcd输出温度、湿度值
  snprintf(strHumid,0x20,"Humidity:%02d%%    ",(int)DHT11.humidity);
  snprintf(strTemp,0x20,"Temperature:%02dC    ",(int)DHT11.temperature);
  lcd.setCursor(0,0);
  lcd.print(strTemp);
  lcd.setCursor(0,1);
  lcd.print(strHumid);

//延迟两秒后再次循环
  delay(2000);
}